[Boblight SupportThread] Update: 11-02-2014, Boblight 0.8R6

Zitat

Original von ernsth77

Hi Gaga32,
ich würde trotzdem mal probieren die Frames per second runter zu drehen und zu hoffen, das es die CPU schafft. 0.10 (Standard) ist 10 FPS und das ist schon recht schnell. 0.20 - 0.25 sollte gerade noch "ruckelfrei" sein und braucht viel weniger Resourcen...

Hallo,

meine Frage wäre somit:
auf was für einen Typ sollte ich boblight konfigurieren?
und soll ich FPS auf 0.20 stellen?

Danke und Gruß

EINE Bitte zum Schluss: Hat jemand noch eine richtige Anleitung für die Dreambox 800 HD PVR?
Ich hatte auch Probleme mit den Kernel Treibern und mit der USB Unterstützung. Daher bin ich mir nicht sicher, ob das alles richtig war

Hallo zusammen,

es läufttttt.

Ich habe derzeit folgende Konfiguration für die ich nicht mal eben eine Anleitung gefunden habe.

Die Konfiguration sieht wie folgt aus:
- Dreambox 800HDPVR (sehr langsame Box)
- ARDUINO MEGA 256
- WS2801 LEDs 50 Stck

boblight.conf ist die aktuelle Version, die mit dem Arduino funktioniert.

Meine Bitte an euch:
Ich würde mich sehr über Verbesserungsvorschläge freuen.

Ein kleines Problem:
Derzeit läuft es, aber die rechte Seite flackert kurz. Aber nur beim dunklen Bild.

Die Installationsschritte werde ich später, in aller ruhe, zusammen schreiben.

Danke und Gruß

poste mal den Sketch, den Du auf den Arduino gespielt hast.

arduino mit ws2801 läuft am besten mit dem unteren sketch. Sehr performant, da ein ringbuffer benutzt wird.

zu beachten:
- mit arduino "rate" unbeding auf 115200 setzen!!
- KEIN postfix !!
- bei "intervall" > 10000 habe ich sporadische flackern festgestellt.

Arduino schafft max. 12 kb/s, bei mehr als 50 LEDs ist es nicht angenehm. Leonardo dagegen schafft ca. 40 kb/s. Ist für boblight besser geeignet.

// Arduino "bridge" code between host computer and WS2801-based digital
// RGB LED pixels (e.g. Adafruit product ID #322).  Intended for use
// with USB-native boards such as Teensy or Adafruit 32u4 Breakout;
// works on normal serial Arduinos, but throughput is severely limited.
// LED data is streamed, not buffered, making this suitable for larger
// installations (e.g. video wall, etc.) than could otherwise be held
// in the Arduino's limited RAM.


// Some effort is put into avoiding buffer underruns (where the output
// side becomes starved of data).  The WS2801 latch protocol, being
// delay-based, could be inadvertently triggered if the USB bus or CPU
// is swamped with other tasks.  This code buffers incoming serial data
// and introduces intentional pauses if there's a threat of the buffer
// draining prematurely.  The cost of this complexity is somewhat
// reduced throughput, the gain is that most visual glitches are
// avoided (though ultimately a function of the load on the USB bus and
// host CPU, and out of our control).


// LED data and clock lines are connected to the Arduino's SPI output.
// On traditional Arduino boards, SPI data out is digital pin 11 and
// clock is digital pin 13.  On both Teensy and the 32u4 Breakout,
// data out is pin B2, clock is B1.  LEDs should be externally
// powered -- trying to run any more than just a few off the Arduino's
// 5V line is generally a Bad Idea.  LED ground should also be
// connected to Arduino ground.


// --------------------------------------------------------------------
//   This file is part of Adalight.


//   Adalight is free software: you can redistribute it and/or modify
//   it under the terms of the GNU Lesser General Public License as
//   published by the Free Software Foundation, either version 3 of
//   the License, or (at your option) any later version.


//   Adalight is distributed in the hope that it will be useful,
//   but WITHOUT ANY WARRANTY; without even the implied warranty of
//   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//   GNU Lesser General Public License for more details.


//   You should have received a copy of the GNU Lesser General Public
//   License along with Adalight.  If not, see
//   <http://www.gnu.org/licenses/>.
// --------------------------------------------------------------------


#include <SPI.h>


// LED pin for Adafruit 32u4 Breakout Board:
//#define LED_DDR  DDRE
//#define LED_PORT PORTE
//#define LED_PIN  _BV(PORTE6)
// LED pin for Teensy:
//#define LED_DDR  DDRD
//#define LED_PORT PORTD
//#define LED_PIN  _BV(PORTD6)
// LED pin for Arduino:
#define LED_DDR  DDRB
#define LED_PORT PORTB
#define LED_PIN  _BV(PORTB5)


// A 'magic word' (along with LED count & checksum) precedes each block
// of LED data; this assists the microcontroller in syncing up with the
// host-side software and properly issuing the latch (host I/O is
// likely buffered, making usleep() unreliable for latch).  You may see
// an initial glitchy frame or two until the two come into alignment.
// The magic word can be whatever sequence you like, but each character
// should be unique, and frequent pixel values like 0 and 255 are
// avoided -- fewer false positives.  The host software will need to
// generate a compatible header: immediately following the magic word
// are three bytes: a 16-bit count of the number of LEDs (high byte
// first) followed by a simple checksum value (high byte XOR low byte
// XOR 0x55).  LED data follows, 3 bytes per LED, in order R, G, B,
// where 0 = off and 255 = max brightness.


static const uint8_t magic[] = {'A','d','a'};
#define MAGICSIZE  sizeof(magic)
#define HEADERSIZE (MAGICSIZE + 3)


#define MODE_HEADER 0
#define MODE_HOLD   1
#define MODE_DATA   2


// If no serial data is received for a while, the LEDs are shut off
// automatically.  This avoids the annoying "stuck pixel" look when
// quitting LED display programs on the host computer.
static const unsigned long serialTimeout = 5000; // 15 seconds


void setup()
{
  // Dirty trick: the circular buffer for serial data is 256 bytes,
  // and the "in" and "out" indices are unsigned 8-bit types -- this
  // much simplifies the cases where in/out need to "wrap around" the
  // beginning/end of the buffer.  Otherwise there'd be a ton of bit-
  // masking and/or conditional code every time one of these indices
  // needs to change, slowing things down tremendously.
  uint8_t
    buffer[256],
    indexIn       = 0,
    indexOut      = 0,
    mode          = MODE_HEADER,
    hi, lo, chk, i, spiFlag;
  int16_t
    bytesBuffered = 0,
    hold          = 0,
    c;
  int32_t
    bytesRemaining;
  unsigned long
    startTime,
    lastByteTime,
    lastAckTime,
    t;


  LED_DDR  |=  LED_PIN; // Enable output for LED
  LED_PORT &= ~LED_PIN; // LED off


  Serial.begin(115200); // Teensy/32u4 disregards baud rate; is OK!


  SPI.begin();
  SPI.setBitOrder(MSBFIRST);
  SPI.setDataMode(SPI_MODE0);
  SPI.setClockDivider(SPI_CLOCK_DIV16); // 1 MHz max, else flicker


  // Issue test pattern to LEDs on startup.  This helps verify that
  // wiring between the Arduino and LEDs is correct.  Not knowing the
  // actual number of LEDs connected, this sets all of them (well, up
  // to the first 25,000, so as not to be TOO time consuming) to red,
  // green, blue, then off.  Once you're confident everything is working
  // end-to-end, it's OK to comment this out and reprogram the Arduino.
  uint8_t testcolor[] = { 0, 0, 0, 255, 0, 0 };
  for(char n=3; n>=0; n--) {
    for(c=0; c<25000; c++) {
      for(i=0; i<3; i++) {
        for(SPDR = testcolor[n + i]; !(SPSR & _BV(SPIF)); );
      }
    }
    delay(1); // One millisecond pause = latch
  }


  Serial.print("Ada\n"); // Send ACK string to host


  startTime    = micros();
  lastByteTime = lastAckTime = millis();


  // loop() is avoided as even that small bit of function overhead
  // has a measurable impact on this code's overall throughput.


  for(;;) {


    // Implementation is a simple finite-state machine.
    // Regardless of mode, check for serial input each time:
    t = millis();
    if((bytesBuffered < 256) && ((c = Serial.read()) >= 0)) {
      buffer[indexIn++] = c;
      bytesBuffered++;
      lastByteTime = lastAckTime = t; // Reset timeout counters
    } else {
      // No data received.  If this persists, send an ACK packet
      // to host once every second to alert it to our presence.
      if((t - lastAckTime) > 1000) {
        Serial.print("Ada\n"); // Send ACK string to host
        lastAckTime = t; // Reset counter
      }
      // If no data received for an extended time, turn off all LEDs.
      if((t - lastByteTime) > serialTimeout) {
        for(c=0; c<32767; c++) {
          for(SPDR=0; !(SPSR & _BV(SPIF)); );
        }
        delay(1); // One millisecond pause = latch
        lastByteTime = t; // Reset counter
      }
    }


    switch(mode) {


     case MODE_HEADER:


      // In header-seeking mode.  Is there enough data to check?
      if(bytesBuffered >= HEADERSIZE) {
        // Indeed.  Check for a 'magic word' match.
        for(i=0; (i<MAGICSIZE) && (buffer[indexOut++] == magic[i++]););
        if(i == MAGICSIZE) {
          // Magic word matches.  Now how about the checksum?
          hi  = buffer[indexOut++];
          lo  = buffer[indexOut++];
          chk = buffer[indexOut++];
          if(chk == (hi ^ lo ^ 0x55)) {
            // Checksum looks valid.  Get 16-bit LED count, add 1
            // (# LEDs is always > 0) and multiply by 3 for R,G,B.
            bytesRemaining = 3L * (256L * (long)hi + (long)lo + 1L);
            bytesBuffered -= 3;
            spiFlag        = 0;         // No data out yet
            mode           = MODE_HOLD; // Proceed to latch wait mode
          } else {
            // Checksum didn't match; search resumes after magic word.
            indexOut  -= 3; // Rewind
          }
        } // else no header match.  Resume at first mismatched byte.
        bytesBuffered -= i;
      }
      break;


     case MODE_HOLD:


      // Ostensibly "waiting for the latch from the prior frame
      // to complete" mode, but may also revert to this mode when
      // underrun prevention necessitates a delay.


      if((micros() - startTime) < hold) break; // Still holding; keep buffering


      // Latch/delay complete.  Advance to data-issuing mode...
      LED_PORT &= ~LED_PIN;  // LED off
      mode      = MODE_DATA; // ...and fall through (no break):


     case MODE_DATA:


      while(spiFlag && !(SPSR & _BV(SPIF))); // Wait for prior byte
      if(bytesRemaining > 0) {
        if(bytesBuffered > 0) {
          SPDR = buffer[indexOut++];   // Issue next byte
          bytesBuffered--;
          bytesRemaining--;
          spiFlag = 1;
        }
        // If serial buffer is threatening to underrun, start
        // introducing progressively longer pauses to allow more
        // data to arrive (up to a point).
        if((bytesBuffered < 32) && (bytesRemaining > bytesBuffered)) {
          startTime = micros();
          hold      = 100 + (32 - bytesBuffered) * 10;
          mode      = MODE_HOLD;
	}
      } else {
        // End of data -- issue latch:
        startTime  = micros();
        hold       = 1000;        // Latch duration = 1000 uS
        LED_PORT  |= LED_PIN;     // LED on
        mode       = MODE_HEADER; // Begin next header search
      }
    } // end switch
  } // end for(;;)
}


void loop()
{
  // Not used.  See note in setup() function.
}

Hallo Sabuha,

vielen Dank für die Infos. Ich werde es Heute Abend testen und im Anshcluss berichten.

Nochmals vielen Dank

Gruß

[quote]Original von Sabuha
arduino mit ws2801 läuft am besten mit dem unteren sketch. Sehr performant, da ein ringbuffer benutzt wird.

zu beachten:
- mit arduino "rate" unbeding auf 115200 setzen!!
- KEIN postfix !!
- bei "intervall" > 10000 habe ich sporadische flackern festgestellt.

Arduino schafft max. 12 kb/s, bei mehr als 50 LEDs ist es nicht angenehm. Leonardo dagegen schafft ca. 40 kb/s. Ist für boblight besser geeignet.

[code]
// Arduino "bridge" code between host computer and WS2801-based digital
// RGB LED pixels (e.g. Adafruit product ID #322). Intended for use
// with USB-native boards such as Teensy or Adafruit 32u4 Breakout;
// works on normal serial Arduinos, but throughput is severely limited.
// LED data is streamed, not buffered, making this suitable for larger
......

Hallo Sabuha,

ich habe jetzt gemacht und die LEDs flackern leider immer noch.

Es sind die ersten 10 LEDs von gesamt 50 LEDs.

Es flackert nur bei schnellen Bildern und bestimmten Farben.

Bei sanften Übergängen bzw. langsamen Bewegungen ist das flackern nicht so stark bzw. oft.

Sonst ist es fast unangenehm und es stört sehr. Trotz dunklen Bildern, ist das Flackern recht hell. Es Blitz kurz auf!!

@ ersnth77:
Als sketch setzte ich das von sabuha ein, aber keine Verbesserung.

Bitte um weitere Ideen.

Danke und Gruß

Zitat

Original von gaga32
Hallo Sabuha,

vielen Dank für die Infos. Ich werde es Heute Abend testen und im Anshcluss berichten.

Nochmals vielen Dank

Gruß

[quote]Original von Sabuha
arduino mit ws2801 läuft am besten mit dem unteren sketch. Sehr performant, da ein ringbuffer benutzt wird.

zu beachten:
- mit arduino "rate" unbeding auf 115200 setzen!!
- KEIN postfix !!
- bei "intervall" > 10000 habe ich sporadische flackern festgestellt.

Arduino schafft max. 12 kb/s, bei mehr als 50 LEDs ist es nicht angenehm. Leonardo dagegen schafft ca. 40 kb/s. Ist für boblight besser geeignet.

[code]
// Arduino "bridge" code between host computer and WS2801-based digital
// RGB LED pixels (e.g. Adafruit product ID #322). Intended for use
// with USB-native boards such as Teensy or Adafruit 32u4 Breakout;
// works on normal serial Arduinos, but throughput is severely limited.
// LED data is streamed, not buffered, making this suitable for larger
......

Alles anzeigen

Es wird ja bald Receiver wie den Xpeed LX3 und ET10000 geben.. die einen hdmi in anschluss haben... ist es möglich das er so genutzt werden kann das z.b. xbox oder ps angeschlossen werden können und boblight dann auch mit einer konsole läuft? das das Bild über den Receiver geschickt wird und boblight sich dann die Bilddaten zu nutze macht?

Hey Speedy!

I found a new resolution which Boblight doesn't process correct: 1912x1072 (Grabber 119x66)

The light basically works, but the color position is not correct. It seems getting worse from top to bottom.

Greetings!

pre-compiled binary for raspberry don't work for me...

-bash: /usr/bin/boblightd: cannot execute binary file

i've compiled new one from speedys boblightd2.1 sources for raspberry with arch-linux which can execute...

/edit

@ Speedy

your optimized boblightd Version don't work with XBMC plugin anymore...

it doesn't make sense for me

that's not useful - i want use my Raspberry boblightd Server with XBMC PC & Dreambox

had to revert to 0.8R3

gaga
Das mit dem flackern ist ein altbekanntes problem, war schon so zu mambas atmolight zeiten so, er meinte es kommt direkt vom decoder.ich merke es an meiner gigablue quad garnicht mehr, aber an einer langsameren box ist es extrem auffällig.wenn an meiner box eine mkv abgespielt wird, sehe ich es auch extrem.ich denke es hat was mit power der box zu tun.

zitat aus speedeys homepage:

What will be fixed/changed in next release:
- Blackbar detection has bugs
- There are some weird flashes in the rightcorner-top on HD
- Sedulight moodlamp get not the good colors.
- More….

there are some...blablabla, ist es bei dir auch in der ecke oben rechts??

ansonsten probier mal die geschwindigkeit mit 35-40%

Hallo zusammen,

wollte mich die Tage an meine Dreambox und Boblight wagen, jedoch habe ich wohl bereits Probleme die LED's überhaupt zum leuchten zu bringen.

Zu meiner Hardware:
- Dreambox 500HD (inkl USB Erweiterung, an dem USB post hängt ein USB HUB an welchem ich den Arduino anschließen möchte)
- Arduino UNO (bzw. ein Clone namens Robotale UNO)
- 50 LED Lichterkette (flach) (12mm WS2801 pixel module,IP66;DC5V input;full color;50pcs a string, aus China http://www.aliexpress.com/snapshot/6004058000.html)

Ich habe bereits Probleme mit der Verkabelung nehme ich an.
Habe mich an mehrer Anleitungen versucht zu halten um überhaupt irgendwie die LED's zum leuchten zu bringen.

Das einzige was erfolgreich lief war das eine einzige LED (erste am Arduino Board) weiß geleuchtet hat.
Sobald ich den Arduino UNO mit der .pde Datei flashe sollten wohl die LED's farblich leuchten, tun Sie jedoch bei mir nicht.

Wollte zuerst die LED's einwandfrei am PC zum laufen bekommen und diese dann an die Dream anschleißen und dort mein Glück versuchen, scheint noch ein weiter Weg für mich zu sein.

Habe mich an der Anleitung von boblightenigma2.net gehalten, jedoch ohne Erfolg, laut Grafik (http://www.boblightenigma2.net…013/06/wiring-diagram.png) muss ich das rote und blaue Kabel der Buchse mit dem DDC Adapter verbinden, dies ging nur indem ich die Kabel (rot/blau) mit einer Zange gekappt habe und anschließend diese mit dem Adapter verbunden habe, anschließend habe ich das selbe mit dem Stecker gemacht (roten & blauen Draht gekappt) und isoliert habe, wie gesagt kein Erfolg.
daraufhin habe ich die Anschlüsse vertauscht (Buchse an Arduino, Stecker an den DC Adapter und es leuchtete nur eine einzelne LED)

Nun zu meinen Fragen bzw Bitten:
- sind die LED's überhaupt geeignet ? (siehe Link unter "Zu meiner Hardware:")
- Was muss ich wie anschleißen um die LED'S korrekt mit dem PC bzw. Dreambox zu verbinden ?
- Was habe ich falsch gemacht ?

Wäre euch sehr dankbar wenn Ihr mich unterstützen könntet.

Mit freundlichen Grüßen
Jay

deine streifen sind ok, müssten laufen.

mit den arduino's ist so'ne sache... es gibt unterschiede zw. den modellen. Auch ich stand anfangs vor den selben problemen, bis ich dann rausgefunden habe, bei welchem modell wo die data und clock signale vorliegen...

schaue mal auf diese seite (Connections):

http://arduino.cc/de/Reference/SPI

bei meinem leonardo musste ich vom ICSP-Block pin 3 und 4 nehmen.

schaue auf deine pixel-platine welche farbe data und welche clock ist, und schließe die leitungen auf die arduino an. Und natürlich den GND auch..

also, es sind nur 3 pins auf der arduino zu belegen (clock, data und gnd)

als sketch kann ich den von mir oben geposteten empfehlen.

EDIT: achte unbedingt auf die pfeilrichtung auf dem ersten pixel!!! wenn du das falsche ende nimmst, kann es nie funktionieren

hi,

erstmal vielen Dank für die Antwort,
Kenne mich mit der Materie leider nicht so aus, aber wie es aussieht ist beim Arduino UNO Data =PIN11 & Clock = 13.

Das mit den Pfeilrichtungen habe ich bislang nicht beachtet, werde ich heute oder morgen mal chechen.

was meinst du mit "pixel-platine" ?

Gruß
jay

ws2801-platine

müsste auf der rückseite zu sehen sein, welcher anschluss was ist...

Zitat

Original von speedyisfast
What is not working in the XBMC plugin can you explain more ?
So i can make it work for you all.

Or maybe we can do some Teamviewer Session ?
Iam online in IRC on this moment.

Kind regards Speedy1985

Good Morning Speedy!

sorry, i was busy yesterday Evening

your pre-compiled binary couldn't execute on my Arch-System - shell shows above error

then i've compiled new one from your sources (this boblightd is only 200kb big, could it be?) - this one can execute without error

but when i connect via XBMC Boblight Plugin then the LED's shine only with Blacklight-Level - no color change - it seems the XBMC-Plugin is able to connect with raspberry

sure, we could make TeamViewer session - but not this Evening - maybe tommorow? on Saturday i have more time

greetings

Zitat

Original von jayfizzle
Hallo zusammen,

wollte mich die Tage an meine Dreambox und Boblight wagen, jedoch habe ich wohl bereits Probleme die LED's überhaupt zum leuchten zu bringen.

Zu meiner Hardware:
- Dreambox 500HD (inkl USB Erweiterung, an dem USB post hängt ein USB HUB an welchem ich den Arduino anschließen möchte)
- Arduino UNO (bzw. ein Clone namens Robotale UNO)
- 50 LED Lichterkette (flach) (12mm WS2801 pixel module,IP66;DC5V input;full color;50pcs a string, aus China http://www.aliexpress.com/snapshot/6004058000.html)

Ich habe bereits Probleme mit der Verkabelung nehme ich an.
Habe mich an mehrer Anleitungen versucht zu halten um überhaupt irgendwie die LED's zum leuchten zu bringen.

Das einzige was erfolgreich lief war das eine einzige LED (erste am Arduino Board) weiß geleuchtet hat.
Sobald ich den Arduino UNO mit der .pde Datei flashe sollten wohl die LED's farblich leuchten, tun Sie jedoch bei mir nicht.

Wollte zuerst die LED's einwandfrei am PC zum laufen bekommen und diese dann an die Dream anschleißen und dort mein Glück versuchen, scheint noch ein weiter Weg für mich zu sein.

Habe mich an der Anleitung von boblightenigma2.net gehalten, jedoch ohne Erfolg, laut Grafik (http://www.boblightenigma2.net…013/06/wiring-diagram.png) muss ich das rote und blaue Kabel der Buchse mit dem DDC Adapter verbinden, dies ging nur indem ich die Kabel (rot/blau) mit einer Zange gekappt habe und anschließend diese mit dem Adapter verbunden habe, anschließend habe ich das selbe mit dem Stecker gemacht (roten & blauen Draht gekappt) und isoliert habe, wie gesagt kein Erfolg.
daraufhin habe ich die Anschlüsse vertauscht (Buchse an Arduino, Stecker an den DC Adapter und es leuchtete nur eine einzelne LED)

Nun zu meinen Fragen bzw Bitten:
- sind die LED's überhaupt geeignet ? (siehe Link unter "Zu meiner Hardware:")
- Was muss ich wie anschleißen um die LED'S korrekt mit dem PC bzw. Dreambox zu verbinden ?
- Was habe ich falsch gemacht ?

Wäre euch sehr dankbar wenn Ihr mich unterstützen könntet.

Mit freundlichen Grüßen
Jay

Alles anzeigen

Hallo Jay,

hast du den Arduino auch am richtigen Ende der LEDs angeschlossen? Mein Bruder hatte das Problem und den Arduino am Ende der WS2801 strips angeschlossen.

Check das hier mal:
http://dbmdb-blog.blogspot.de/…-schritt-fur-schritt.html

gaga:

hab heute mein arduino pro micro bekommen und gleich mal angschlossen. Vorher hatte ich mit meiner vu+ keine langzeittest durchgeführt. Wenn ich mir nicht eingebildet habe, war auch auf meinem system ein flackern zu sehen...

so hab ich das sketch basierend auf dem fastLED-Lib mal hochgeladen.... wenn es wieder keine einbildung ist, denke ich, dass das bild ruhiger ist

probier mal aus, nur bei diesem sketch muss die anzahl der LEDs im source-code geändert werden.

wenn du einen verdreher zw. Grün/Blau hattest, müsstest du ggf. in der boblight.conf oder im sketch ändern:

[color]
name            red
rgb             FF0000
gamma           1.0
adjust          1.0
blacklevel      0


[color]
name            green
rgb             00FF00 #oder 0000FF
gamma           1.3
adjust          1.0
blacklevel      0


[color]
name            blue
rgb             0000FF #oder 00FF00
gamma           1.0
adjust          1.0
blacklevel      0

oder im sketch:

FastLED.addLeds<WS2801, RGB>(leds, NUM_LEDS);

oder

FastLED.addLeds<WS2801, RBG>(leds, NUM_LEDS);

also, unbedingt anzahl der LEDs vor dem hochladen anpassen!

probier mal aus...

Hi,

Danke für eure Rückmeldungen und Tipps!
Habe nun das Problem das dadurch das meine LED's wasserdicht sind, diese mit eeiner Gummischicht überzogen sind und man somit auf der Platine nichts sehen kann, weder Pfeile noch Buchstaben sind zu erkennen.!
kann denn was kaputt gehen wenn ich irgendwas falsch anschließen sollte?
Würde es dann einfach mal durchtesten bis es klappt, falls es klappt,

Gruß
Jay

EDIT: Naja habs heute mrogen getestet, die KAbelbelegung war falsch, nach einigen Versuchen schmorte mir eine LED weg

Kann das an dem Netzteil gelegen haben ?

wie hattest du angeschlossen?

so müsste richtig sein:

rot: +
weiss: -
grün: data
blau: clock

dir richtung musst du irgendwie ablesen können, meistens ist ein pfeil auf dem eingegossenen teil auch drauf.